blob: 9b0928c42e51d4aef42c9e4e2d7ca601ffc14285 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
|
#-------------------------------------------------
#
# Project created by QtCreator 2015-12-25T20:24:49
#
#-------------------------------------------------
QT += core gui
greaterThan(QT_MAJOR_VERSION, 4): QT += widgets
TARGET = qmidiplayer
TEMPLATE = app
CONFIG += c++11
SOURCES += main.cpp\
qmpmainwindow.cpp \
../core/qmpmidiplay.cpp \
../core/qmpmidiread.cpp \
qmpplistwindow.cpp \
qmpchannelswindow.cpp \
qmppresetselect.cpp \
qmpchanneleditor.cpp \
qmpefxwindow.cpp \
qmpinfowindow.cpp \
qmpsettingswindow.cpp \
qmphelpwindow.cpp \
qdialskulpturestyle.cpp \
qmpplugin.cpp \
qmpcustomizewindow.cpp \
../core/qmpmidioutrtmidi.cpp \
../core/qmpmidioutfluid.cpp
HEADERS += qmpmainwindow.hpp \
../core/qmpmidiplay.hpp \
qmpplistwindow.hpp \
qmpchannelswindow.hpp \
qmppresetselect.hpp \
qmpchanneleditor.hpp \
qmpefxwindow.hpp \
qmpinfowindow.hpp \
qmpsettingswindow.hpp \
qmphelpwindow.hpp \
qdialskulpturestyle.hpp \
../include/qmpcorepublic.hpp \
qmpplugin.hpp \
qmpcustomizewindow.hpp \
../core/qmpmidioutrtmidi.hpp \
../core/qmpmidioutfluid.hpp
FORMS += qmpmainwindow.ui \
qmpplistwindow.ui \
qmpchannelswindow.ui \
qmppresetselect.ui \
qmpchanneleditor.ui \
qmpefxwindow.ui \
qmpinfowindow.ui \
qmpsettingswindow.ui \
qmphelpwindow.ui \
qmpcustomizewindow.ui
TRANSLATIONS += translations/qmp_zh_CN.ts
DEFINES += BUILD_MACHINE=$${QMAKE_HOST.name}
unix{
isEmpty(PREFIX) {
PREFIX = /usr/local
}
BUILDM = $$(QMP_BUILD_MODE)
isEmpty(BUILDM) {
message(Building in normal(debugging) mode...)
}
else {
message(Building in packaging mode...)
DEFINES += QMP_BUILD_UNIX_PACKAGE
}
exists("/usr/include/RtMidi.h") {
DEFINES += RT_MIDI_H=\\\"/usr/include/RtMidi.h\\\"
}
exists("/usr/include/rtmidi/RtMidi.h") {
DEFINES += RT_MIDI_H=\\\"/usr/include/rtmidi/RtMidi.h\\\"
}
QMAKE_CXXFLAGS_RELEASE -= -O2
QMAKE_CXXFLAGS_RELEASE += -O3
QMAKE_LFLAGS_RELEASE -= -O1
QMAKE_LFLAGS_RELEASE += -O3
BINDIR = $$PREFIX/bin
target.path = $$BINDIR
DATADIR = $$PREFIX/share
INSTALLS += target desktop iconbmp iconsvg iconxpm doc docimg appdata menu mimetype
desktop.path = $$DATADIR/applications
desktop.files += $${TARGET}.desktop
iconbmp.path = $$DATADIR/icons/hicolor/64x64/apps
iconbmp.files += ../img/qmidiplyr.png
iconsvg.path = $$DATADIR/icons/hicolor/scalable/apps
iconsvg.files += ../img/qmidiplyr.svg
iconxpm.path = $$DATADIR/pixmaps
iconxpm.files += ../img/qmidiplyr.xpm
doc.path = $$DATADIR/qmidiplayer/doc
doc.files += ../doc/*
docimg.path = $$DATADIR/qmidiplayer/img
docimg.files += ../img/mainw.png ../img/chanw.png ../img/chparaw.png ../img/qmidiplyr.png
appdata.path = $${DATADIR}/appdata
appdata.files += $${TARGET}.appdata.xml
menu.path = $${DATADIR}/menu
menu.files += ./menu/$${TARGET}
mimetype.path = $$DATADIR/mime/packages
mimetype.files += $${TARGET}.mime
QMAKE_CXXFLAGS += -Wall
LIBS += -lfluidsynth -lrtmidi -ldl
}
win32{
DEFINES += RT_MIDI_H=\\\"RtMidi.h\\\"
#change these before building...
LIBS += e:/libs/fluidsynth/libfluidsynth.dll.a winmm.lib
Release:LIBS += e:/libs/rtmidi/rtmidi.lib
Debug:LIBS += e:/libs/rtmidi/rtmidid.lib
INCLUDEPATH += e:/libs/fluidsynth/include
INCLUDEPATH += e:/libs/rtmidi
RC_FILE = qmidiplayer.rc
}
RESOURCES = resources.qrc
|
