s-tui eapi 8

1 files changed, 38 insertions, 0 deletions

diff --git a/app-benchmarks/s-tui/s-tui-1.1.4-r1.ebuild b/app-benchmarks/s-tui/s-tui-1.1.4-r1.ebuild
new file mode 100644
index 0000000..01ca0a2
--- /dev/null
+++ b/app-benchmarks/s-tui/s-tui-1.1.4-r1.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+DISTUTILS_USE_PEP517=setuptools
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Stress-Terminal UI monitoring tool"
+HOMEPAGE="https://amanusk.github.io/s-tui/"
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/amanusk/${PN}.git"
+	EGIT_SUBMODULES=()
+else
+	# Pypi source doesn't include tests
+	SRC_URI="https://github.com/amanusk/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+
+RDEPEND="
+	>=dev-python/urwid-2.0.1[${PYTHON_USEDEP}]
+	>=dev-python/psutil-5.6.0[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests unittest
+
+pkg_postinst() {
+	elog "To get additional features, some optional runtime dependencies"
+	elog "may be installed:"
+	elog ""
+	optfeature "Stress options in program menu" app-benchmarks/stress
+}